Устанавливает или возвращает атрибуты папок. Является, в зависимости от атрибутов, свойством для записи/чтения или только для чтения.

object.Attributes [= newattributes]

Параметры
object Обязательный. Всегда задает имя объекта Folder или File
newattributes Необязательный. Если элемент newattributes задан, то он содержит новые атрибуты для объекта, указанного в элементе object.
Элемент newattributes может содержать любое из следующих значений или любую логическую комбинацию из приведенных значений:

Константа 	Значение 			Описание 
Normal 		0 			Обычный файл. 	Атрибуты не установлены. По умолчанию 
ReadOnly 	1 				Только для чтения. Установлен атрибут чтение/запись 
Hidden 		2 			Скрытый файл. Установлен атрибут чтение/запись 
System 		4 			Системный файл. Установлен атрибут чтение/запись 
Volume 		8 			Метка тома дискового накопителя. Установлен атрибут только для чтения 
Directory 	16 			Папка или каталог. Установлен атрибут только для чтения 
Archive 		32 			Файл был изменен после последнего резервирования. Установлен атрибут чтение/запись 
Alias 		1024 			Ссылка или ярлык. Установлен атрибут только для чтения 
Compressed 	2048 			Сжатый файл. Установлен атрибут только для чтения 

Пример
Следующий код иллюстрирует использование свойства Attributes для файла:

Sub SetClearArchiveBit(filespec)
    Dim fs, f, r
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFile(fs.GetFileName(filespec))
    If f.attributes and 32 Then
        r = MsgBox("The Archive bit is set, do you want to clear it?", vbYesNo, "Set/Clear Archive Bit")
        If r = vbYes Then 
            f.attributes = f.attributes - 32
            MsgBox "Archive bit is cleared."
        Else
            MsgBox "Archive bit remains set."
        End If
    Else
        r = MsgBox("The Archive bit is not set. Do you want to set it?", vbYesNo, "Set/Clear Archive Bit")
        If r = vbYes Then 
            f.attributes = f.attributes + 32
            MsgBox "Archive bit is set."
        Else
            MsgBox "Archive bit remains clear."
        End If
    End If
End Sub